// goblin.txt
// A creature which becomes less confident when outnumbered by enemies
// and regains confidence when the numbers are on its side
// Otherwise behaves like basicnpc
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.

begincreaturescript;

variables;

short aggression,courage,target,first;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	courage = 100;
break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		inc_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE;
	if(enemies_nearby(8) > friends_nearby(8)){ 
		if(courage == 100 && party_can_see_loc(char_loc_x(my_number()), char_loc_y(my_number())) == 1)
			print_str("The goblin looks nervous");
		if(creature_type(my_number())==1){ //regular
			courage = 25;
			aggression = 50;
		}
		else if(creature_type(my_number())==9){ //fighter
			courage = 50;
			aggression = 75;
		}
		set_courage(my_number(), courage);
		set_aggression(my_number(),aggression);
	}
	else if(courage < 100){
		 if(party_can_see_loc(char_loc_x(my_number()),char_loc_y(my_number())) == 1)
			print_str("The goblin looks more confident");
		courage = 100;
		aggression = 100;
		set_courage(my_number(), courage);
		set_aggression(my_number(),aggression);
	}
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16){
			first = 1;
			set_state(3);
		}
		else
			set_target(ME,-1);
	}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		first = 1;
		set_state(3);
	}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		first = 1;
		set_state(3);
	}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	else if (get_memory_cell(0) == 0) {
		fidget(ME,50);
	}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if(enemies_nearby(8) > friends_nearby(8)){
		if(courage == 100 && party_can_see_loc(char_loc_x(my_number()), char_loc_y(my_number())) == 1)
			print_str("The goblin looks nervous");
		if(creature_type(my_number())==1){ //regular
			courage = 25;
			aggression = 50;
		}
		else if(creature_type(my_number())==9){ //fighter
			courage = 50;
			aggression = 75;
		}
		set_courage(my_number(), courage);
		set_aggression(my_number(),aggression);
	}
	else if(courage < 100){
		if(party_can_see_loc(char_loc_x(my_number()),char_loc_y(my_number())) == 1)
			print_str("The goblin looks more confident");
		courage = 100;
		aggression = 100;
		set_courage(my_number(), courage);
		set_aggression(my_number(),aggression);
	}
	if(first == 0) //avoid potential for inifinite loop
		select_target(ME,8,0);
	first = 0;
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
	}
	begin_talk_mode(get_memory_cell(3));
break;